Add to Comment

DEVONthink Automation
1

There is currently a function allowing us to ‘Set Title As’ (contextual menu). Would it be possible to have one allowing us to ‘Add to Comment’?

Thank you.

2

That’s easily scriptable:


tell application "DEVONthink Pro"
	try
		activate
		if not (exists think window 1) then error "No window open."
		if not (exists content record) then error "No document selected."
		
		set this_text to the selected text of think window 1 as string
		if this_text is "" then error "No text selected."
		
		set this_record to content record
		set this_comment to comment of this_record as string
		if this_comment is not "" then set this_comment to this_comment & return
		set comment of this_record to (this_comment & this_text) as string
	on error error_message number error_number
		if the error_number is not -128 then
			try
				display alert "DEVONthink Pro" message error_message as warning
			on error number error_number
				if error_number is -1708 then display dialog error_message buttons {"OK"} default button 1
			end try
		end if
	end try
end tell

Just save this script in the folder ~/Library/Application Support/DEVONthink Pro.