Ok, the script is a modified version of this script, Christian Grunenberg from DEVONtechnologies very kindly and patiently helped me with that. I run different versions of this script on messages in Apple Mail from a KeyboardMaestro palette or by calling the script via LaunchBar. You can also have a rule execute it.
I only added the tagging part for you. Please note my comments below, but first here’s the script:
-- Import selected Mail messages & attachments to DEVONthink Pro.
-- Created by Christian Grunenberg on Mon Mar 05 2012.
-- Copyright (c) 2012-2013. All rights reserved.
-- POSIX path of destination database
property pDatabasePath : "/Users/me/Documents/DEVONthinkPro/datenbanken/mail.dtBase2"
-- this string is used when the message subject is empty
property pNoSubjectString : "(no subject)"
tell application "Mail"
try
-- Location of destination groups.
set pEmailLocation to "/in/projectx"
set pMessageLocation to pEmailLocation
set pAttachmentLocation to "/Anhaenge"
tell application id "com.devon-technologies.thinkpro2"
if not (exists current database) then error "No database is in use."
if pDatabasePath is "" then
set destination_database to inbox
else
set destination_database to open database pDatabasePath -- Ensure that the database is open
end if
set email_group to create location pEmailLocation in destination_database
set message_group to create location pMessageLocation in destination_database
set attachment_group to create location pAttachmentLocation in destination_database
end tell
set theSelection to the selection
set theFolder to (POSIX path of (path to temporary items))
if the length of theSelection is less than 1 then error "One or more messages must be selected."
repeat with theMessage in theSelection
my importMessage(theMessage, theFolder, email_group, message_group, attachment_group)
end repeat
on error error_message number error_number
if error_number is not -128 then display alert "Mail" message error_message as warning
end try
end tell
on importMessage(theMessage, theFolder, theEmailGroup, theMessageGroup, theAttachmentGroup)
tell application "Mail"
try
tell theMessage
set {theDateReceived, theDateSent, theSender, theSubject, theSource, theReadFlag} to {the date received, the date sent, the sender, subject, the source, the read status}
end tell
if theSubject is equal to "" then set theSubject to pNoSubjectString
set theAttachmentCount to count of mail attachments of theMessage
tell application id "com.devon-technologies.thinkpro2"
set theRecord to create record with {name:theSubject & ".eml", type:unknown, creation date:theDateSent, modification date:theDateReceived, URL:theSender, source:(theSource as string)} in theMessageGroup
set unread of theRecord to (not theReadFlag)
set label of theRecord to 5
set tags of theRecord to (tags of theRecord) & "exampletag1" & "exampletag2"
end tell
repeat with theAttachment in mail attachments of theMessage
set theFile to theFolder & (name of theAttachment)
tell theAttachment to save in theFile
tell application id "com.devon-technologies.thinkpro2"
set theAttachmentRecord to import theFile to theAttachmentGroup
set unread of theAttachmentRecord to (not theReadFlag)
set URL of theAttachmentRecord to theSender
end tell
end repeat
move theMessage to mailbox named "DEVONthink"
on error error_message number error_number
if error_number is not -128 then display alert "Mail" message error_message as warning
end try
end tell
end importMessage
You have to modify these lines:
Replace this with the correct path to your database and the databases name and your username:
property pDatabasePath : "/Users/me/Documents/DEVONthinkPro/datenbanken/mail.dtBase2"
Replace this with the path to your target folder in the database. In my example “in” is a group on the root level of the database and “projectx” is a subgroup of this.
set pEmailLocation to "/in/projectx"
Replace this with the path in your database, that you want the attachments to be filed to (yes, the attachments will be exorted to DEVONthink separately too with this script, unless you modify the script):
set pAttachmentLocation to “/Attachments"
Replace “exampletag1” and “exampletag2” with your tags and add a third or remove the second, depending on how many tags you want:
set tags of theRecord to (tags of theRecord) & "exampletag1" & "exampletag2"
PS: As I understand that command also imports existing tags, but I am not sure!
PPS: If you want to assign no tag(s) simply delete this line.
This sets the status of the message in DEVONthink to “read”:
set unread of theRecord to (not theReadFlag)
This sets the label for the message to the 5th label in > DEVONthink Pro Office>preferences > colors > labels. If you don’t want to label the message, simply delete that line:
set label of theRecord to 5
This moves the exported message to a folder in Apple Mail called “DEVONthink”, which I created. I did so, so that I do not export messages more than once (avoid duplicates) and because I do not keep messages in Apple Mail, therefore it is ok for me, when the messages are moved from their original location after exporting.
You must evaluate yourself, if that makes sense to you or if you export by date to avoid exporting messages over and over again. Another option would be, to apply a color to exported messages or to flag them within Apple Mail, either via the rule or manually or by modifying this script.
If you do not want the messages to be moved within Apple Mail, I think you just can delete that line.
move theMessage to mailbox named "DEVONthink"
I hope I have it all covered. I am by no means capable of AppleScript, but feel free to ask, if you have any questions and I hope the good people on this board will help us. 
—
PS: If you want to apply this script via a rule in Apple Mail to incoming messages, please note, that there could be problems with POP-accounts since the release of OS10.8. Apple has changed something there. I assume, they have not fixed it since then.
On incoming emails from IMAP it works just fine as well of course on existing emails.
