There might be an easier way to do this, that has since cropped up - but at the time I tried to find a solution, I ended up with the below – which still works perfectly.
I downloaded/purchased Fastscripts [red-sweater.com/fastscripts/], which lives in the Menu-bar.
I then added the script below, courtesy of Christian, to the Fastscripts menus, and added a shortcut key to invoke it.
When I am in Outlook, I select the message, invoke the shortcut key, and up pops the dialogue box asking me where I want to place the email inside DTPO.
As mentioned - there might now be a better way of doing this, but I use this to get my Outlook (Mac) 15.38 messages into DTPO, and works a treat.
Hope this helps.
The script from Christian:
-- Import selected Microsoft Outlook messages to DEVONthink Pro.
-- Created by Christian Grunenberg on Dec 08 2010.
-- Copyright (c) 2010-2015. All rights reserved.
-- this string is used when the message subject is empty
property pNoSubjectString : "(no subject)"
tell application "Microsoft Outlook"
try
set theSelection to the selected objects
if theSelection is {} then error "One or more messages must be selected."
tell application id "DNtp"
if not (exists current database) then error "No database is in use."
set theGroup to preferred import destination
end tell
repeat with theMessage in theSelection
try
set theSubject to subject of theMessage
set theSender to sender of theMessage
set theSender to (address of theSender) as string
set theSource to source of theMessage
set theDateReceived to time received of theMessage
set theDateSent to time sent of theMessage
if theSubject is equal to "" then set theSubject to pNoSubjectString
set theCategories to {}
set theList to (category of theMessage)
repeat with theCategory in theList
set theCategories to theCategories & (name of theCategory)
end repeat
set isFlagged to true
if todo flag of theMessage is (not flagged) then set isFlagged to false
set isUnread to is read of theMessage
tell application id "DNtp"
set theRecord to create record with {name:theSubject & ".eml", type:unknown, creation date:theDateSent, modification date:theDateReceived, URL:theSender, source:(theSource as string)} in theGroup
if theCategories is not {} then
set theTags to tags of theRecord
set theTags to theTags & theCategories
set tags of theRecord to theTags
end if
if isFlagged then set state of theRecord to true
if isUnread then set unread of theRecord to true
end tell
end try
end repeat
on error error_message number error_number
if the error_number is not -128 then display alert "Outlook" message error_message as warning
end try
end tell
I have downloaded the FastScripts but am not sure where to find this script and what to do with it in order to use it in Outlook. Anyone know how to do this? What I am trying to do is to be able to send an email directly from Outlook to a folder within DevonThink Pro.
Thanks.