Updating webarchives

[pete31]

@mksBelper

I then go through them all and correct the URL - if/when I can find it - in the URL field of the Inspector. I assume that’s the right/best place to update a URL, isn’t it?

But in the View/Edit Pane at the bottom of my window, the old (incorrect/out-of-date) URL remains for each webarchive.

That’s funny. I have just written a script the other day that does exactly that.

Note:

• It is only necessary to use this script if you captured a part of a website.
• If you’ve captured via Clip to DEVONthink, i.e. you captured a whole website, then it’s not necessary to use this script.

-- Replace internal webarchive URL with DEVONthink's URL

-- Note: It is only necessary to use this script if you captured a part of a website. If you've captured via Clip to DEVONthink, i.e. you captured a whole website, then it's not necessary to use it.

tell application id "DNtp"
	try
		set theRecords to selected records
		if theRecords = {} then error "Please select a webarchive"
		
		repeat with thisRecord in theRecords
			set thisType to (type of thisRecord) as string
			if thisType is in {"webarchive", "«constant ****wbar»"} then
				set thisURL to URL of thisRecord
				if thisURL ≠ "" then
					do shell script "/usr/libexec/PlistBuddy -c " & quoted form of ("set \":WebMainResource:WebResourceURL\" " & thisURL) & space & quoted form of (path of thisRecord as string)
				end if
			end if
		end repeat
		
	on error error_message number error_number
		if the error_number is not -128 then display alert "DEVONthink" message error_message as warning
		return
	end try
end tell