Hi, I’m using Vienna as my RSS reader (while trying Endo, which does not have a built-in browser). I like Vienna for reading these feeds, but selected postings I would like to import into one of my DT Pro databases.
Is there anyone who has the same set-up and has an Applescript for it?
I also use DEVONthink Pro and Vienna (which i really like best of all the Newsreaders i tried - and its for free!).
Having no Applescript-Skills at all i copied and pasted this together some time ago:
tell application "Vienna"
set theVersion to version
if theVersion is greater than or equal to "2.0.0.2007" then
set theArticle to the current article
if theArticle is not false then
set theName to the title of theArticle
set theText to the body of theArticle
tell application "DEVONthink Pro"
create record with {name:theName, type:html, source:theText}
activate
end tell
end if
else
display dialog "This script requires Vienna 2.0.0.2007 or later"
end if
end tell
One could also put some other information Vienna provides via AppleScript to the right places in the DEVONthink Document:
tell application "Vienna"
set theVersion to version
if theVersion is greater than or equal to "2.0.0.2007" then
set theArticle to the current article
if theArticle is not false then
set theName to the title of theArticle
set theDate to the date of theArticle
set theURL to the link of theArticle
set theComment to "Clipping from Vienna."
set theText to "<html><body><p><a href=\"" & theURL & "\"><bold>" & theName & "</bold></a></p><p><font color=#800000>Author: " & the author of theArticle & ".</font></p><small>" & the body of theArticle & "</small></body></html>"
tell application "DEVONthink Pro"
create record with {name:theName, type:html, date:theDate, URL:theURL, source:theText, comment:theComment}
activate
end tell
end if
else
display dialog "This script requires Vienna 2.0.0.2007 or later"
end if
end tell
And it works great, many thanks! Yes, Vienna is a very nice reader, and that for free! The only alternative I like is Endo, because endo combines Vienna’s two first windows, Folders / Articles, which makes for easier viewing (certainly on a 12" iBook but even on my iMac) and you can also just look at new mail without having to see all subscriptions. But endo does not have an internal browser, and the colours are sometimes just too much. Having this script (in addition to the ones I load wholesome into DT via their modelscript) probably settles things in favour of Vienna…
Thanks for the script. I modified your code a little to make Vienna pass a URL from the frontmost document to Devonthink. While I have it create a variable for theComment,I find it mildly useful.
tell application "Vienna"
set theVersion to version
if theVersion is greater than or equal to "2.0.0.2007" then
set theTitle to the title of the current article
if theTitle is not false then
set theURL to the link of the current article
tell application "DEVONthink Pro"
create record with {name:theTitle, type:link, URL:theURL}
activate
end tell
end if
else
display dialog "This script requires Vienna 2.0.0.2007 or later"
end if
end tell
One more script. This one grabs the Vienna content to a webarchive. Often I prefer to use webarchives incase the online content changes.
tell application "Vienna"
set theVersion to version
if theVersion is greater than or equal to "2.0.0.2007" then
set theTitle to the title of the current article
if theTitle is not false then --checks to make sure vienna has a URL
set theURL to the link of the current article
--set theCurrentWindow to the document
tell application "DEVONthink Pro"
set theTitle to create record with {name:theTitle, type:link, URL:theURL} --creates record with URL from vienna
set theWindow to open window for record theTitle
repeat while loading of theWindow
delay 1
end repeat --waits for window to refresh
set theURL to URL of theWindow
set theSource to source of theWindow
set theName to get title of theSource
set theData to web archive of theWindow
set theArchive to create record with {name:theName, type:html, URL:theURL, source:theSource}
set data of theArchive to theData --creates archive
delete record theTitle --removes the temp URL record
end tell
end if
else
display dialog "This script requires Vienna 2.0.0.2007 or later"
end if
end tell