Capture/Save PDF from Safari direct to DT?

DEVONthink
1

I know I can Export my PDF from Safari to a folder and then import the folder into DT.

I tried clipping using the webclipper however the best I can get is one page.

What am I missing?

  • Mark
2

Which format did you actually use? One page or paginated?

3

I tried both formats. One page got me half a page and paginated got a full page,

Example URLs: https://liubovborisova.com/images/UUacadenWriting/ArticleAnalysisReadingGuide.pdf
https://nbrosowsky.github.io/documents/QALMRI-instructions.pdf

4

Did you use exactly these URLs for clipping? Then DEVONthink should store the original PDF document actually, no matter whether the format was single-page or paginated PDF.

5

I did use these urls, as an example I get this:

Inboxes_—_https___liubovborisova_com_images_UUacadenWriting_ArticleAnalysisReadingGuide
Inboxes_—_https___liubovborisova_com_images_UUacadenWriting_ArticleAnalysisReadingGuide1057×940 196 KB

As you see from the metadata - its one page and 295KB.

6

What operating system are you running?

7

MacOS 11.5.2
MacBook Pro (13-inch, M1, 2020)
Browser Safari

Yes I have restarted DevonThink a couple of times in this game.

8

@cgrunenberg :The only thing unusual I see is the name is the full URL. Otherwise, I clipped both URLs as paginated PDFs with no issue.

9

I restarted Safari and DevonThink just in case together were the problem. No luck.

Then - I clipped to Markdown just to see what would happen. A miracle - clipping to Markdown saved a PDF+text. This is beginning to feel like quantum physics - spooky and strange. It is however missing truth and beauty.

10

I believe it’s up and charmed though. :stuck_out_tongue:

11

I had to double check (sorry). Strange and Charmed are a pair. Top/Bottom are another, however I prefer Truth and Beauty - even if those names fell out of favour.

12

Just taking a little poetic license with the flavors :wink:

13

You can make a favourite folder in Finder, like “Save to DT”, and attach the script below to this folder.

-- Script to move saved file to DT
-- Created by Silverstone on 14.04.2021
-- Updated on 26.04.2021 to escape working on MS Office TEMP files

on adding folder items to this_folder after receiving added_items
	set added_items to set_viable_list out of added_items
	try
		if (count of added_items) is greater than 0 then
			tell application id "DNtp"
				try
					set theGroup to (get selection)
					if theGroup is {} then
						set theGroup to display group selector
					else
						set theGroup to item 1 of theGroup
					end if
					if kind of theGroup is not "group" then set theGroup to current group
					set theImported to 0
					repeat with theItem in added_items
						try
							set thePath to POSIX path of theItem
							set theRecord to import thePath to theGroup
							perform smart rule trigger import event record theRecord
							if exists theRecord then do shell script "rm -R " & quoted form of thePath
							log message info "Item '" & filename of theRecord & "' is imported successfully to '" & name of theGroup & "'" record theRecord
							set theImported to theImported + 1
						end try
					end repeat
					activate
					delay 0.5
					display notification (theImported as string) & " new item(s) was imported into '" & name of theGroup & "'" with title "Importing into Devonthink"
					set theAnswer to display dialog "Do you want to open '" & filename of theRecord & "'?" with title "Open the last imported file?" buttons {"Cancel", "Open"} default button "Open"
					if button returned of theAnswer is "Open" then
						set thePath to path of theRecord
						do shell script "open " & quoted form of thePath
					end if
				on error ErrMsg
					tell application "Finder" to set theName to name of the theItem
					log message "There was a problem importing a file" info "Importing of file '" & theName & "' into the group '" & name of theGroup & "' is failed. Error: " & ErrMsg
				end try
			end tell
		end if
	end try
end adding folder items to

on set_viable_list out of theList
	set theClearList to {}
	repeat with theItem in theList
		set thePath to POSIX path of theItem
		tell application "Finder" to set theName to name of the theItem
		if thePath does not end with ".download:" and thePath does not end with ".crdownload:" then
			if theName does not start with "~$" then
				set the end of theClearList to theItem
			end if
		end if
	end repeat
	return theClearList
end set_viable_list

It will import any file to current DT group.

1 Like
14

This looks very useful. Please forgive my ignorance with the next step.

I can read the code and I’m assuming its applescript. How do I attach the Script to a folder?

Cheers
Mark

15
  1. Save this script as a .scpt file in ~/Library/Scripts/Folder Action Scripts (paste it in AppleScript editor and save)
  2. Right click on the folder in Finder - Services - Folder actions
  3. Choose the script from the list
  4. Enjoy )

Don’t forget to place this folder in Finder’s sidebar favourites, to see it in every system Save dialog

1 Like
16

For someone who like me finds themselves fighting their Mac - How to make your Library folder visible in the Finder in OS X 10.9 (Mavericks) or later - IS&T Contributions - Hermes will help you make the finder visible.

Hint View Options is your friend.

17

))) Sorry, I thought you know this…
I use Path Finder for long time, so I’ve forgotten all these Finder strange limitations

2 Likes
18

[Odd tried to reply by email and it never arrived]

Strangely, I use Pathfinder as well. It too needs the view option set to make the library folder visible.

Between DT, Hazel, Pathfinder, Keyboard Maestro and TheBrain I wonder if I’m making my world massively over complicated. All I’m missing is BetterTouchTool to complete the madness.

Cheers
Mark

19

Try Multitouch instead of BTT, I personally found it more useful and simple.
For Path Finder just add this icon to the toolbar:
image
Clicking it will make all hidden items visible in current folder