Collecting all images from an rss feed

DEVONthink Tips
1

My primary use of Devon Think is to subscribe to and download my online activities. While the text is stored locally, however, it seems like the images are not.

Is there a way to batch download the pictures and keep them locally? Also, is there a setting I can change? I can’t go back and grab the expired rss feeds so I’m hoping there is a script I can run to go back and grab the images in older posts.

Thanks!
Schmüdde
www.schmudde.net
www.earthcirclefilms.com
Twitter: @dschmudde

2

You could select the news and run Scripts > Download > Create Offline Archive. Unfortunately it’s broken, version 2.0.7 will include this fixed script:


tell application id "com.devon-technologies.thinkpro2"
	try
		set this_selection to the selection
		if this_selection is {} then error "Please select some contents."
		show progress indicator "Scanning Selection..." steps -1
		my offlineArchive(this_selection)
		hide progress indicator
	on error error_message number error_number
		hide progress indicator
		if the error_number is not -128 then display alert "DEVONthink Pro" message error_message as warning
	end try
end tell

on offlineArchive(theChildren)
	local this_child, this_URL, this_source, this_type
	tell application id "com.devon-technologies.thinkpro2"
		repeat with this_child in theChildren
			try
				set this_type to type of this_child
				if this_type is group then
					step progress indicator name of this_child as string
					my offlineArchive(children of this_child)
				else if this_type is html then
					step progress indicator name of this_child as string
					set this_URL to URL of this_child
					set this_source to source of this_child
					my addRef2Downloads(get embedded images of this_source base URL this_URL)
					my addRef2Downloads(get embedded objects of this_source base URL this_URL)
					my addRef2Downloads(get embedded sheets and scripts of this_source base URL this_URL)
				end if
			end try
		end repeat
	end tell
end offlineArchive

on addRef2Downloads(these_links)
	local these_records
	tell application id "com.devon-technologies.thinkpro2"
		try
			repeat with this_link in these_links
				if not (exists record with URL this_link) then add download this_link with automatic
			end repeat
		end try
	end tell
end addRef2Downloads
3

Thanks for this answer. I finally updated to the DevonThink 2.0.7 and ran the script.

This is useful - but what I’d really like is for the image to be linked to the original article. Right now, the offline hypertext is linked to the image on the web but if there was some way to relate/link the offline image and offline text in the database itself, that would be most useful. Is there a way to do this?

Thanks,
Schmüdde
www.schmudde.net
www.earthcirclefilms.com

4

No. But as long as both the news and the downloaded images are stored in the same database, DEVONthink Pro is also able to display them offline.