Dateien im Eingang automatisch umbenennen

International Deutsch
,
1

Hallo,

ich suche nach einer Möglichkeit in DEVONthink (Regel etc.), mit der Dateien, die im Eingang landen, automatisch umbenannt werden können. Ziel ist, dass im Dateinamen Leerzeichen und Umlaute entsprechend ersetzt werden sollen.

Vorher Nacher
" " _
Ä Ae
ä ae
Ö Oe
ö oe
Ü Ue
ü ue
ß ss

Ich hab schon entdeckt, dass bei den intelligenten Regeln auch ein Skript verwendet werden kann. Ich bin mir sicher, dass es hiermit bestimmt funktioniert könnte. Da mir das Know-How für das Erstellen eines brauchbaren Skriptes fehlt, frage ich mal hier in die Runde, ob wer was weiß.

2

Willkommen @Bastian
Dieses Skript ändert diakritische Zeichen in den Namen der übereinstimmenden Datensätze. Es wird mit einer Aktion Skript anwenden > AppleScript in einer intelligenten Regel verwendet.

Hinweis: Die mehreren Zeilen in der Wiederholungsschleife dienen nur der visuellen Klarheit für Neueinsteiger. Ich persönlich würde sie in meinen eigenen Skripten nicht auf diese Weise aufteilen.

(Übersetzt mit DeepL)

on performSmartRule(theRecords)
	set od to AppleScript's text item delimiters
	tell application id "DNtp"
		repeat with theRecord in theRecords
			set recName to (name of the theRecord)
			repeat with val in {¬
				{d:"ö", r:"oe"}, ¬
				{d:"Ö", r:"Oe"}, ¬
				{d:"ü", r:"ue"}, ¬
				{d:"Ü", r:"Ue"}, ¬
				{d:"ä", r:"ae"}, ¬
				{d:"Ä", r:"Ae"}, ¬
				{d:"ß", r:"ss"}}
				set AppleScript's text item delimiters to (d of val)
				set recName to text items of recName
				set AppleScript's text item delimiters to (r of val)
				set recName to recName as string
			end repeat
			-- Do stuff with recName
			set name of theRecord to recName
		end repeat
		set AppleScript's text item delimiters to od
	end tell
end performSmartRule
1 Like
3

Vielen Dank für die schnelle Hilfe @BLUEFROG
Genau das habe ich gesucht. Das Skript funktioniert perfekt. Vielen Dank dafür.

4

Herzlich willkommen. Ich freue mich, Ihnen helfen zu können. :slight_smile: