How do I change Devonthink's language? (SOLVED)

hi to all,

i am new to devonthink and after some weeks of testing it, i bought devonthink pro office with devon agent.
those are great tools; very powerfull and lots of potential. unfortunately the GUI / the ergonomics are not at its best yet, hence i often surf forums, tutorials or even on devon academy. mostly those refer to the english version of Devonthink.
besides, the german translation is less than optimal.
since i use DT on a german system (mac os 10.5), DT is in german as well. so my question is, how do i change the operating language in DT to english?

thanx a lot for help.

close DevonThink, select it in the Finder, press cmd-I (Information) and deselect Deutsch (or whatever language your system is working on) in the language section.

Other Option: The documentation pdf has a section ordered by menus so it is easy to spot what is the desired English word (I had to look up one or two myself this way to understand what the Forum is talking about :wink:)

Hope that helps
Johannes

hi johannes,

thanks a lot; it worked perfectly. i didn’t know this trick which seems to be part of mac os x. turns out to be quite useful :smiley:

Same problem for me, but the old solution (CMD-I) seems not working anymore. Any idea to change it under OSX Sierra?

Thanks!

Ralf

You can change the primary language in System Preferences > Language & Region then launch DEVONthink, but so will other apps you launch after that. You could change the language back and DEVONthink will remain in chosen language, but this will not be persistent after DEVONthink restarts.

Thanks for the fast reply, Jim! Mhh, what a pity that there’s no permanent solution ;-( I read about deleting the German language folder in the resources of the app, maybe this would be the best solution (though I have to do it again after updating).

Have a nice day!

Best

Ralf

I would not suggest deleting anything inside the application if you want things to run as expected.

There’s a script for that:

-- Language Chooser:
-- make an app run in language other than the system language
-- change is permanent
-- Re-run & press OK without selecting language to return to the system's language
-- Cancel button does same
--
-- 'choose application' not suitable: it will launch the app
set theApp to choose file of type "com.apple.application-bundle" with prompt "Find me an app:" --> alias
set POSIXpathToApp to POSIX path of theApp
-- get languages available in app
set langs to do shell script "mdls -name kMDItemLanguages -raw " & quoted form of POSIXpathToApp
-- clean up reply
set text item delimiters to {",", space, return}
set langs to text items 2 thru -2 of langs
repeat with x from 1 to count langs
	-- eliminate empty strings
	if item x of langs = "" then set item x of langs to missing value -- NG
	-- eliminate double quotes around items containing a dash
	if item x of langs contains "\"" then set item x of langs to text 2 thru -2 of item x of langs
end repeat
set langs to text of langs -- drops 'missing value' items
set text item delimiters to ""

tell application "System Events"
	-- read app's bundle id from info.plist; other methods will launch app
	set infoRecord to value of property list file (POSIXpathToApp & "Contents/info.plist")
	set bundleID to CFBundleIdentifier of infoRecord
	-- get app's plist, using bundle id
	set myPrefsFile to (path to preferences folder of user domain as text) & bundleID & ".plist"
end tell
set POSIXpathToPlist to POSIX path of myPrefsFile

try
	-- select one or no language
	set myLang to choose from list langs multiple selections allowed no empty selection allowed yes with prompt "Choose a language:"
	
	if (myLang is {}) or (myLang is false) then -- empty selection or Cancel button, revert to system language
		-- delete appropiate key in plist
		do shell script "defaults delete " & bundleID & " AppleLanguages"
	else
		-- write to plist; allows add & overwrite with one command
		tell application "System Events"
			set plistFile to property list file POSIXpathToPlist
			make new property list item at end of property list items of contents of plistFile ¬
				with properties {kind:record, name:"AppleLanguages", value:myLang}
		end tell
	end if
on error errStr number errNum
	display dialog "Error: " & errNum & return & errStr buttons "OK" default button 1
end try

There will be no feedback, but the selected application will now launch in the selected language. It does not change the language of a running application; you must quit & relaunch.

On a Mac with English set as system language, to set german as DEVONThinks Language paste this in the terminal:


defaults write $(mdls -name kMDItemCFBundleIdentifier -raw /Applications/DEVONthink\ Pro.app) AppleLanguages "(de)"

1 Like

Interesting approach.